Onde isso faz falta?

Suponha que você queira manter 2 imagens iguais aparecendo na tela para simular um efeito de espelho ou que você precise mostrar um thumb e uma imagem grande e esta imagem é carregada dinâmicamente. Você não pode simplesmente dar addChild uma segunda vez, pois o seu objeto vai se mover. Sim, ele vai sumir do lugar antigo e aparecer no novo lugar, mas por quê? Não era para ser uma referência na memória? Sim, continua sendo, mas… Todo DisplayObject possui uma propriedade parent que faz referência ao DisplayObjectContainer onde ele foi adicionado. Sempre que o método addChild é chamado o valor da propriedade parent é alterado e consequentemente o DisplayObject deixa de estar no lugar anterior, porque afinal de contas ele só tem um pai.

Para Bitmap felizmente existe um jeitinho, mas para outros DisplayObject, não. Mas o que um Bitmap tem de tão especial? Um objeto Bitmap tem em sua composição um objeto BitmapData, e este por sua vez tem o método clone implementado. É na propriedade bitmapData que estão armazenadas todas as características da imagem. Segue um exemplo com um Bitmap gerado pelo código, mais especificamente um quadrado vermelho, veja como é simples:

// criando um bitmap (quadrado)
var bitmap:Bitmap = new Bitmap(new BitmapData(100, 100, false, 0xBB0000));
 
// adicionando bitmap no palco
this.addChild(bitmap);
 
// criando um novo bitmap com o clone do bitmap data
var bitmapClone:Bitmap = new Bitmap(bitmap.bitmapData.clone());
 
// modificando o posicionamento p/ enxergarmos os 2 elementos
bitmapClone.x = 100;
bitmapClone.y = 100;
 
// adicionando o clone no palco
this.addChild(bitmapClone);

Se uma imagem é carregada dinamicamente o processo é exatamente o mesmo, já que todo objeto Bitmap possui em sua composição um BitmapData sendo ele carregado externamente ou não. Então aproveitamos o que a imagem já tem. Segue um exemplo:

// declara e instancia um objeto loader
var loader:Loader = new Loader();
 
// adiciona listener para o carregmento da imagem
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, handleLoadComplete);
 
// define uma url para carregamento
var urlRequest:URLRequest = new URLRequest("http://www.nyan.com.br/ico/it.png");
 
// inicia o processo de carregamento
loader.load(urlRequest);
 
// handle para o evento de complete
function handleLoadComplete(event:Event):void 
{
	// cria referencia para a imagem carregada
	var image:Bitmap = loader.content as Bitmap;	
 
	// adiciona a imagem no palco
 	this.addChild(image);
 
	// cria um novo bitmap e adiciona um clone 
	// do BitmapData contido no Bitmap carregado
	var imageCopy:Bitmap = new Bitmap(image.bitmapData.clone());
 
	// adicionando copia no palco
	this.addChild(imageCopy);
	// mudando posicionamento para enxergarmos
	imageCopy.x = 100;
 
}

Tem mais uma coisa interessante nisso: se você declarar um novo Bitmap, atribuindo a ele um BitmapData existente mas sem chamar o método clone, também vai funcionar. A diferença é que se você fizer qualquer alteração no bitmapData através de qualquer um dos Bitmaps, ambos serão alterados, o que não acontece quando invocamos o método clone, pois ele sempre retorna uma nova instância. Este é um bom exemplo pra entender a diferença entre instâncias e referências.